let

    // Connect to the parent folder holding all files and subfolders
    Source = Folder.Files("C:\Camtasia Projects\Power Query - Avoid Scary Queries"),

    // Standardize the casing of the file extensions (using UPPERCASE)
    Uppercase_File_Extensions = Table.TransformColumns(Source,{{"Extension", Text.Upper, type text}}),

    // Filter to keep only files in the "Excel Files" folder and subfolders
    Filter_By_Path = Table.SelectRows(Uppercase_File_Extensions, each Text.Contains([Folder Path], "\Excel Files\")),

    // Filter to keep only XLSX files
    Filter_By_XLSX_Files = Table.SelectRows(Filter_By_Path, each Text.Contains([Extension], ".XLSX")),

    // Remove all columns of folder metadata EXCEPT the [Content] column
    Keep_Only_Content = Table.SelectColumns(Filter_By_XLSX_Files,{"Content"}),

    // Extract the file metadata, but only for proper tables, not sheets
    Extract_Only_Tables = Table.AddColumn(Keep_Only_Content, "ExtractedData", each Table.SelectRows(Excel.Workbook([Content]), each ([Kind] = "Table"))),

    // Delete the [Content] column (column of Binaries)
    Delete_Binaries = Table.RemoveColumns(Extract_Only_Tables,{"Content"}),

    // Expand the file metadata from the [ExtractedData] column (also, reorder columns and rename "Item" to "State")
    Expand_Tables = Table.ExpandTableColumn(Delete_Binaries, "ExtractedData", {"Item", "Data"}, {"State", "Data"}),

   // Expand the table columns of data from the [Data] column
    Expand_Data = Table.ExpandTableColumn(Expand_Tables, "Data", {"Transaction #", "Item Number", "Quantity", "Item Amount"}, {"Transaction #", "Item Number", "Quantity", "Item Amount"}),

    // Set the Data Types for the columns
    Set_Data_Types = Table.TransformColumnTypes(Expand_Data,{{"State", type text}, {"Transaction #", Int64.Type}, {"Item Number", Int64.Type}, {"Quantity", Int64.Type}, {"Item Amount", Currency.Type}}),

    // Remove any total rows (rows with text are rendered as errors by previous step)
    Remove_Error_Rows = Table.RemoveRowsWithErrors(Set_Data_Types, {"Transaction #"})

in

    Remove_Error_Rows